PCの時刻同期の設定を行うコマンド（バッチファイル）用意しました

次の記事で紹介した、PCの時刻を正確に合わせる方法を行うコマンド（バッチファイル）を用意しました。
Windowsのデフォルト設定では、時間がよくずれるので使ってみてください。

PCの時刻を正確に合わせる３通りの設定方法 パソコン鳥のブログ

以下から set_ntp.zip をダウンロードし、中の set_ntp.bat を実行して下さい。
実行で「ユーザアカウント制御」ダイアログが表示された場合は、「はい」を押します。

https://onedrive.live.com/download?resid=D54242E7C106EE41!129&authkey=!AJyKLLQBV__bzsA&ithint=file%2czip

次の設定で時刻同期を行うようになります。

• 設定方法：
  w32tmコマンドでの設定
• NTPサーバ：
  ntp.jst.mfeed.ad.jp、ntp.nict.jp
  ラウンドロビンにより、それぞれのサーバは複数台が参照されます
• 時刻同期を行う間隔：
  86400秒（１日）

set_ntp.bat の内容は以下になります。

set_ntp.bat

@echo off
cd /d %~dp0
for /f "tokens=3 delims=\ " %%i in ('whoami /groups^|find "Mandatory"') do set LEVEL=%%i
if NOT "%LEVEL%"=="High" (
@powershell -NoProfile -ExecutionPolicy unrestricted -Command "Start-Process %~f0 -Verb runas"
exit
)
net start W32Time 2> NUL
echo ***** 時刻同期間隔の設定
w32tm /config /manualpeerlist:"ntp.jst.mfeed.ad.jp,0x9 ntp.nict.jp,0x9" /syncfromflags:MANUAL /update
reg add HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\TimeProviders\NtpClient /v SpecialPollInterval /t REG_DWORD /d 86400 /f 
echo ***** Windows Time サービスの設定
net stop W32Time
sc config w32time start= delayed-auto
net start W32Time
echo ***** 設定完了
echo 何かキーを押すと終了します
pause > NUL

実行すると、次のように表示します。
最後に何かキーを押して終了です。

***** 時刻同期間隔の設定
コマンドは正しく完了しました。
この操作を正しく終了しました。
***** Windows Time サービスの設定
Windows Time サービスを停止中です.
Windows Time サービスは正常に停止されました。
[SC] ChangeServiceConfig SUCCESS
Windows Time サービスを開始します.
Windows Time サービスは正常に開始されました。
***** 設定完了
何かキーを押すと終了します